|
| Thread: Script 57 Option 057 |  This thread is pages long: 1 2 3 · «PREV / NEXT» |
|
artu
Promising
Undefeatable Hero
My BS sensor is tingling again
|
posted December 12, 2012 01:29 AM |
|
|
Quote:
From the viewpoint of a scripter, that is not much of an exact specification. It leaves the following issues unanswered:
1) Is Salamandre's version sufficient? If so, thank him and we are done. (I'll thank him anyway: Thanks, Salamandre. Looks good.)
2) Or do you want some specific object to be used to trigger the script?
3) And if so, do you want this object added to maps during wogification?
4) Adding things to somebody's else's mod (WoG Revised) is beyond my authority and not something I can commit to.
5) In my experience, vague statements such as "fix it but don't change anything" lead to specification-creep after things are fixed and users find that actual use of the script does not meet their expectations; be aware that in that case my response is apt to be "You got what you asked for. You're welcome."
1) I'm sure it is (and thanks of course), but the point is to
3) play random maps with this script, so yes.
2) School of War is already the chosen object according to the info page.
4) Well, since it was your modification that produced the custom scripts page in wog's Era version in the first place, i thought you guys were kind of like a team (of friends) anyway.
5)The dont change anything part was about not asking any new features so we can get the ten votes easily, if i ask for new features others will come up with ideas too and then we're screwed 
|
|
JimV
Responsible
Supreme Hero
|
|
posted December 12, 2012 03:43 AM |
|
|
Since Salamandre already did 99% of the work, I've added the School of War part for the Troop Training script:
ZVSE
* TroopSchool, JHV, Dec. 11, 2012
* Fnord/Salamandre Troop Training School of War
*Salamandre: use any object you like, just trigger FU509 after visit and build your mod on. [School of War, type 107]
*It has no check for experience option, maybe should be added. [Check]
*I tried to open hero window first (in TEW is triggered from custom button in hero screen)
*with special era event FU77004 but can't make it work.
*Would be better if it opens hero window before action. [Not possible in OB trigger except by custom DL.]
*Important: was for custom map so it may conflict with free wogification.
* uses v300-v307 temporarily during visit, FU507-FU510 [all OK per WoG 3.58f List of Claimed]
!?OB107&1000; pre-visit School of War
!!UN:P900/?y1; stack exp. option
!!FU&y1<>1:E; exit if stack exp. not enabled
!!FU509:P;
!!OB998:C?y1; get control word (number)
!!HE-1:V9/y1/?y2; School of War (#1=9, see HE:V)
!!OB998&y2<>0:S; disable normal "go away" message if visited
!$OB107&1000; post-visit
!!OB998:R; re-enable normal messages for non-visited Heroes
!?FU509;
!!VRv300:C-1/-1/-1/-1/-1/-1/-1/0; JHV
!!DO507/0/6/1:P300; [Build text strings for dialogue box]
!!OW:R-1/6/?y1;
!!VRz-1:S^Select a stack to train to the next rank. Available gold: %Y1^;
!!VRz-2:S^I'll do it later.^;
!!VRz8:S^Train all to next level for %V307 gold.^; JHV
!!VRz8&v307<1:S^^; JHV
!!IF:G1/1/256/-1/1/2/3/4/5/6/7/8/-2/0/0/0; [Display dialogue box] JHV
!!FU&v1=256:E; [Exit if player chose to come back later] JHV
!!VRy-10&v1=1:S0; [Stack 0 selected: y-10]
!!VRy-10&v1=2:S1; [Stack 1 selected: y-10]
!!VRy-10&v1=4:S2; [Stack 2 selected: y-10]
!!VRy-10&v1=8:S3; [Stack 3 selected: y-10]
!!VRy-10&v1=16:S4; [Stack 4 selected: y-10]
!!VRy-10&v1=32:S5; [Stack 5 selected: y-10]
!!VRy-10&v1=64:S6; [Stack 6 selected: y-10]
!!IF&v1=128/y1<v307:Q1/6/y-8/1^Not enough gold!^;
!!DO510/y-10/y-10/1&v1<>128:P300; JHV
!!DO510/0/6/1&v1=128/y1>=v307:P300; JHV
*!UN:R3/-1;
!!FU509:P;
!?FU510; x16=troop slot
!!VRy1:Sx1+x16; index to prices JHV
!!VRy-8:Svy1; get price for troop x16 JHV
!!FU&y-8<0:E; exit if priceless JHV
!!HE-1:C0/x16/?v2/?v3/?v4/2; [v2=type, v3=number, v4=exp]
!!UN&v3=1:N3/8/v2/0; [Monster name (singular): z8]
!!UN&v3>1:N3/8/v2/1; [Monster name (plural): z8]
!!MA:Lv2/?y-6; [Monster level (0..6): y-6]
!!VRy-6:+1; [Add 1 to monster level: y-6]
!!FU508:Py-6/v4/v2; [Get rank: y-20]
!!VRy-5:Sy-20 +1; [Next rank to train creatures to: y-5]
!!VRy-7:Sy-6; [Copy of monster level: y-7]
!!VRy-9:Sv2 :2 *2; [Check if monster is upgraded: y-9]
!!VRy-7&y-9<>v2/v2<=131:+1; [Add 1 more level if monster is upgraded: y-7]
!!VRy-7&v2>=150/v2<=158:+2; [Add 2 more if monster is level 8: y-7]
*!VRy-8:Sv3 *y-5 *y-6 *y-7:2; [Calculate cost: y-8] JHV
*!VRy-8&v1975=4::2; halve cost for estates specialists JHV
!!OW:R-1/6/?y-11; [Player's gold: y-11]
!!IF&y-11<y-8:Q1/6/y-8/1^Not enough gold!^;
!!FU&y-11<y-8:E; [Exit if player doesn't have enough gold]
!!IF:Q1/21/v2/6/y-8/17/y-5/1^DONE!^;
!!VRy-13:Sy-11 -y-8; [Player's new gold: y-13]
!!OW:R-1/6/y-13; [Set player's new gold: y-13]
[Set new rank for troops: y-5=new rank]
!!HE-1:C0/x16/d/d/y-5/12;
[Build text strings for dialogue box]
!?FU507; x1=start of price table, price-->v[x1+x16], sum of prices-->v[x1+7]
!!HE-1:C0/x16/?y1/?y2/?y3/2; [y1=type, y2=number, y3=experience]
!!VRy4:Sx16 +1; [Index for z variable to store text strings (z1..z7)]
!!VRzy4:S^^; [Initialize z variables to empty strings]
!!FU|y1<0/y2<1:E; [Skip if no monster in this slot]
!!UN&y2=1:N3/8/y1/0; [Monster name (singular): z8]
!!UN&y2>1:N3/8/y1/1; [Monster name (plural): z8]
!!MA:Ly1/?y6; [Monster level (0..6): y6]
!!VRy6:+1; [Add 1 to monster level: y6]
!!FU508:Py6/y3/y1; [Get rank: y-20]
!!VRy5:Sy-20 +1; [Next rank to train creatures to: y5]
!!FU&y5>10:E; [Skip if stack is already at rank 10]
!!VRy7:Sy6; [Copy of monster level: y7]
!!VRy9:Sy1 :2 *2; [Check if monster is upgraded: y9]
!!VRy7&y9<>y1/y1<=131:+1; [Add 1 more to monster level if upgraded: y7]
!!VRy7&y1>=150/y1<=158:+2; [Add 2 more if monster is level 8: y7]
!!VRy8:Sy2 *y5 *y6 *y7:2; [Calculate cost: y8]
**VRy8&v1975=4::2; estates specialists
!!VRzy4:S^Train %Y2 %Z8 to Rank %Y5 for %Y8 gold.^;
!!VRy9:Sx1+x16; index to price table JHV
!!VRvy9:Sy8; JHV
!!VRy10:Sx1+7; index to total price JHV
!!VRvy10:+y8; JHV
[Get rank of stack: y-20]
[x1=monster level (1..7), x2=current experience, x3=monster number]
!?FU508;
!!VRe1:S2 :5 +8; [e1=8.4]
!!VRy1:Sx2 :x1; [Base experience for level 1..7 creatures: y1]
!!VRy1&x3>=150/x3<=163:Sx2 :e1; [Base exp. for level 8 creatures: y1]
!!VRy-20&y1<1000:S0; [Rank 0]
!!VRy-20&y1>=1000/y1<2000:S1; [Rank 1]
!!VRy-20&y1>=2000/y1<3200:S2; [Rank 2]
!!VRy-20&y1>=3200/y1<4600:S3; [Rank 3]
!!VRy-20&y1>=4600/y1<6200:S4; [Rank 4]
!!VRy-20&y1>=6200/y1<8000:S5; [Rank 5]
!!VRy-20&y1>=8000/y1<10000:S6; [Rank 6]
!!VRy-20&y1>=10000/y1<12200:S7; [Rank 7]
!!VRy-20&y1>=12200/y1<14700:S8; [Rank 8]
!!VRy-20&y1>=14700/y1<17500:S9; [Rank 9]
!!VRy-20&y1>=17500:S10; [Rank 10]
Notes:
1) I checked variable and function usage vs. the WoG 3.58f List of the Claimed, and there will be no interference with the WoG scripts. I don't know about other custom/mod scripts.
2) The School of War has a primary function, which operates in tandem with the new troop-training function. Since a Hero who has used the primary function might return to get more troop experience, I eliminated the normal "visited/go away" message. (No action of this kind was specified or prohibited so this decision was in spec.)
3) Under Era 2, add this script to Data/s under whichever mod you prefer (or make a new mod folder for it). I call it TroopSchool.erm but you can name it anything you like. Wogification will add it to a map (if its mod is active), but it will not work unless stack experience is enabled (per Salamandre's comment).
4) Under WoG 3.58f add it to a map as a Timed Event (as described in ERM Help) or add it to any WoG script.
|
|
JimV
Responsible
Supreme Hero
|
|
posted December 12, 2012 09:48 PM |
bonus applied by angelito on 14 Dec 2012. |
Edited by JimV at 03:04, 14 Dec 2012.
|
Since I did one request with only two votes (since most of the work was already done), it is only fair that I do the original request also. Both scripts and an input file (NeutBst.txt) for the Neutral Units scripts are at box.com.
As I said, I was not familiar with either script when I started. Imagine my surprise to learn that script57 (Neutral Units) does not increase the growth of neutral armies, except for those in guarded objects (neutral Towns, Creature Banks, Crypts, Derelict Ships, etc.)! Since none of these are apt to contain 4000 Diamond Dragons [edit--no, sorry, it was 100 Diamond Dragons that was mentioned], I guess the problem there is due to the creature growth built into Heroes 3 - except that script57 does set minimum starting values for neutral army sizes. These apply only to hostile creatures (not those which will join a Hero) for which the "creatures do not grow" box is not checked in the Map Editor. Starting at a larger value will cause a group of creatures to reach their maximum growth a little sooner.
Anyway, I have assigned unclaimed permanent variables to the parameters which script57 does apply to enhance neutral creatures, and revised the script to read these values from a text file under Data (Data/NeutBst.txt). If the file is not found, the original script values are used as defaults. Explanations of the parameters are given in the text file, which is listed below:
--------------------------------------
[NeutralData]
7320=14
7321=7
7322=5
7323=4
7324=3
7325=4
7326=1
7327=15
7328=20
7329=30
7330=40
7331=50
7332=100
7333=1
7334=10
7335=3
7336=2
7337=9
[DefaultsDescriptions]
7320=14 days between increases to Level 1 creature exp. rank at Easy difficulty
7321=7 days between increases to Level 1 creature exp. rank at Normal difficulty
7322=5 days between increases to Level 1 creature exp. rank at Hard difficulty
7323=4 days between increases to Level 1 creature exp. rank at Expert difficulty
7324=3 days between increases to Level 1 creature exp. rank at Impossible difficulty
7325=4 days between increases to creature combat properties (A, D, Health)
7326=1 numerator/ |of factor by which neutral creatures' Health increment is
7327=15 denominator|calculated [Health=>Health*(1+(num./den.)*(time/{7325 value})]
7328=20 min. starting size of all Lvl 8 and some Lvl 7 hostile, neutral, growing troops
7329=30 min. starting size of some Level 1-3 and Level 7 hostile, neutral, growing troops
7330=40 min. starting size of some Level 1-3 hostile, neutral, growing troops
7331=50 min. starting size of some Lv1 1, some Lvl 3, & all Lvl 4-6 growing hostiles
7332=100 minumum starting troop size of hostile Peasants which are set to grow
7333=1 numerator/ |of weekly troop size factor for guarded objects (Towns, Cr Banks,)
7334=10 denominator| [troop size => (1+num./den.)*size]
7335=3 numerator/ |of multiple of basic creature growth used to fill 1st slot of a
7336=2 denominator|guarded object if that slot is empty [no. = (cr growth)*num./denom.]
7337=9 weekly percent chance -1 of cr upgrade (9=>10%/week) of a guard slot
NOTE: changes made to this file during a Heroes 3 session will not take effect until H3 has been quit and restarted if the file has already been read during the session before the changes were made.
Change the first set of 7320-7337 values to affect script57 (Neutral Monster experience growth, combat properties growth, and starting troop size). The second set of values are for explanatory purposes and are not read by the script.
The basic parameters 7320-7324 are increased with creature (town) level. Levels 2 & 3 have double the value, Levels 4 & 5 have triple, etc.
The starting values 7328-7332 are increased by 1-4 randomly.
This file is read from (Heroes 3 Folder)/Data (not under Mods if you are using Era 2). If it is not found there the default values will be used.
Download link for this file and script57JV.erm: https://www.box.com/s/i4hwirisu3sofng0va8v
script57JV.erm should be renamed script57.erm and placed in Data/s (after moving the original to a backup folder) under WoG 3.58f. It should replace "21 wog - neutral units.erm" in WoG/Data/s under Era 2.
----------------------------------
Increasing the time intervals (days) and decreasing the factors (decreasing the numerators and/or increasing the denominators) will make script57's effect easier; doing the opposite will make the difficulty greater.
Only basic, minimum testing has been done, so there may be bugs. Thorough testing would require playing one or more games to completion, but that is outside my development budget.
Update - the comments which I added to the end of the NeutBst.txt file after testing cause it to be read incorrectly by ERM. I have removed the comments and placed them in a separate text file, NeutBstREADME.txt. The new NeutBst.txt and README file are at the box.com link.
|
|
CrimsonW
Hired Hero
|
|
posted December 12, 2012 11:41 PM |
|
|
|
Thank you JimV I hope this weekend or even sooner I will be able to use it and test it.
|
|
artu
Promising
Undefeatable Hero
My BS sensor is tingling again
|
|
posted December 13, 2012 02:12 AM |
|
|
|
thanks jim, you are a good person.
|
|
majaczek
Supreme Hero
Work at Magic Dimmension
|
|
posted December 13, 2012 09:12 AM |
|
|
Nope artu, JimV is a hero, moreover a famous one 
|
|
master_learn
Legendary Hero
walking to the library
|
|
posted December 13, 2012 12:21 PM |
|
|
Should be responsible.
____________
"I heard the latest HD version disables playing Heroes. Please reconsider."-Salamandre
|
|
JimV
Responsible
Supreme Hero
|
|
posted December 14, 2012 12:58 AM |
|
Edited by JimV at 15:12, 15 Dec 2012.
|
Note that AI players get no benefit from the Troop Training script. (None was specified.)
Also note that, using EVME (thanks to Bersy) (it comes with Era 2 under Tools), the parameters of the Neutral Units script (57) can be changed during a game, for convenience in testing. The v-variable numbers are the same as the index numbers in NeutBst.txt (v7320-v7337).
Update - the comments which I added to the end of the NeutBst.txt file after testing cause it to be read incorrectly by ERM. I have removed the comments and placed them in a separate text file, NeutBstREADME.txt. The new NeutBst.txt and README file are at the box.com link.
I plan to add this to the TroopSchool script: since AI Heroes will visit a School of War only once, they will get one free experience rank for all their troops. I will not update the script at the link for a while in case there are objections.
Update 2 - I question this line in the TroopSchool script:
!!VRy1&x3>=150/x3<=163:Sx2 :e1; [Base exp. for level 8 creatures: y1]
I think this should apply to creature numbers 132-135 and 196 also. As the script is now, Faerie Dragons, Rust Dragons, etc. cannot be upgraded past rank 9.
Update 3 (final?) - Since there were no objections or even comments, I have re-uploaded TroopSchool.erm at box.com with these additions:
1) AI Heroes get a free one-rank upgrade to all their troops. (They will only visit once.)
2) The script now works for all level 8 creatures (e.g., Dragoliches, Azure Dragons), not just for non-neutral ones (e.g., Lords of Thunder, Diamond Dragons).
|
|
artu
Promising
Undefeatable Hero
My BS sensor is tingling again
|
|
posted December 15, 2012 04:06 PM |
|
|
|
well i wasnt going to say anything but if you are already still at it, also adding a daily limit would be good for balance issues like a unit pack can only be upgraded once a day. then a message like 'X is too tired to train more today, come back tomorrow' can pop up. right now you can train them from scratch to ace in a single day which is overpowered.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
|
posted December 15, 2012 11:54 PM |
|
|
You said don't change anything, and now backbone modifications are requested. 
What if others prefer it in original spirit: train as much as you have the funds?
Yes, is overpowered, as the entire wog is. Yet, the cost is high and can cripple your economy early.
____________
Era II mods and utilities
|
|
JimV
Responsible
Supreme Hero
|
|
posted December 16, 2012 05:13 AM |
|
|
My initial impression in testing was that the costs for rank zero to rank one seemed low, but they get more expensive for higher ranks. Had I ever used the script before I might have suggested some modification to the cost structure for consideration before starting work; or maybe not, seeing as the numbers came from Fnord.
If the script seems to make games against the AI too easy, one way to make the AI more challenging would be to set the AI to gain experience more rapidly than human players (via the WoG Settings). In that case, using the Fnord/Salamandre script might be a necessity.
|
|
Fnord
Promising
Famous Hero
|
|
posted December 17, 2012 02:02 AM |
|
Edited by Fnord at 02:03, 17 Dec 2012.
|
This script was created for 3.59, and since we never even got close to any sort of release there was very limited testing on 3.59 scripts (just myself and any team members who decided to try them out when initially released to the group).
Therefore, balance testing of this script and any of the "new" scripts I wrote has never occurred, beyond extremely limited initial tests and personal games, so please don't count on the numbers being sacred. 
Thank you everyone who worked on this to make it more useable for current players. It's nice to see the scripts don't go to waste.
But...has all the flavor text been removed now? *sniff sniff*
Quote:
My initial impression in testing was that the costs for rank zero to rank one seemed low, but they get more expensive for higher ranks. Had I ever used the script before I might have suggested some modification to the cost structure for consideration before starting work; or maybe not, seeing as the numbers came from Fnord.
If the script seems to make games against the AI too easy, one way to make the AI more challenging would be to set the AI to gain experience more rapidly than human players (via the WoG Settings). In that case, using the Fnord/Salamandre script might be a necessity.
____________
|
|
JimV
Responsible
Supreme Hero
|
|
posted December 17, 2012 04:30 AM |
|
|
I'll see if I can find the original flavor text, as it is probably my fault if some was removed (back when I converted some 3.59 code back to 3.58f some time ago). I have a prejudice against using jokes in a script which will be used over and over again, because there are TV commercials which I like the first few times I see them, but find irritating after I have seen them about 100 times.
Thanks for your help in learning ERM (by examples), and for the cameo roles you play in "New Magic", "The Swords of Night and Day", "The Dragon Slaughter v2.07", and anywhere else that I need an iconic wizard.
|
|
artu
Promising
Undefeatable Hero
My BS sensor is tingling again
|
|
posted December 17, 2012 09:05 AM |
|
|
Quote:
I have a prejudice against using jokes in a script which will be used over and over again, because there are TV commercials which I like the first few times I see them, but find irritating after I have seen them about 100 times.
Exactly. That's what i was talking about in the emerald tower thread. Keeping it simple is always better.
|
|
Fnord
Promising
Famous Hero
|
|
posted December 17, 2012 10:07 AM |
|
Edited by Fnord at 20:18, 17 Dec 2012.
|
Yes, certainly long passages of flavor text can get tedious and won't be re-read often, so I do appreciate that reducing the number of clicks is generally a good thing. I don't recall if my original script showed the initial message(s) every single visit or not but the ideal would be to show it only once per player per game.
You're very welcome for the ERM examples (from my scripts and any I contributed to the ERM Help itself)! I'm glad my scripts (and other WoG Team member scripts too), and comments and examples helped you and others learn some of the workings of ERM.
And that's most flattering to learn I've been immortalized in several of your maps. I had no idea. But I really haven't played Heroes or WoG in so long...keep meaning to...one of these days.
Quote:
I'll see if I can find the original flavor text, as it is probably my fault if some was removed (back when I converted some 3.59 code back to 3.58f some time ago). I have a prejudice against using jokes in a script which will be used over and over again, because there are TV commercials which I like the first few times I see them, but find irritating after I have seen them about 100 times.
Thanks for your help in learning ERM (by examples), and for the cameo roles you play in "New Magic", "The Swords of Night and Day", "The Dragon Slaughter v2.07", and anywhere else that I need an iconic wizard.
____________
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
|
posted December 17, 2012 11:12 AM |
|
|
My fault too: the script was modified to trigger from clicking custom button in hero screen, thus the flavor text had no place, was just a quick training. Of course the original text should be back if school of war is the trigger. When I pasted it here I forgot about this important detail, thanks to Fnord for remembering us.
____________
Era II mods and utilities
|
|
Fnord
Promising
Famous Hero
|
|
posted December 17, 2012 09:04 PM |
|
|
Hey, no worries! But yeah, would be cool to reinstate it for first visits if possible (with maybe an easy way to edit the script to remove it for those who really don't care about it).
Quote:
My fault too: the script was modified to trigger from clicking custom button in hero screen, thus the flavor text had no place, was just a quick training. Of course the original text should be back if school of war is the trigger. When I pasted it here I forgot about this important detail, thanks to Fnord for remembering us.
____________
|
|
JimV
Responsible
Supreme Hero
|
|
posted December 18, 2012 12:55 AM |
|
|
The TroopSchool.erm script has been modified to display this message the first time a School of War is visited in a game:
The message and its one-time-only code was taken directly from the original version of the script, except that instead of flag 214, variable v1413 is used to prevent repeat messages. Variable v1413 is claimed by WoG script 37, but is not used by that or any other WoG 3.58f script, so by making this slight change, no new Claim (as in the List of the Claimed) is necessary.
The modified script has been uploaded to the same box.com address.
|
|
Fnord
Promising
Famous Hero
|
|
posted December 18, 2012 01:15 AM |
|
|
Thanks, Jim!
Quote:
The TroopSchool.erm script has been modified to display this message the first time a School of War is visited in a game:
____________
|
|
JimV
Responsible
Supreme Hero
|
|
posted December 18, 2012 02:15 AM |
|
|
In the hour or so between my previous comment and now, I suddenly thought of a possible glitch having to do with v1413, and made another change to TroopSchool and re-uploaded. I apologize to anyone who downloaded it between then and now. Nothing too terrible will happen with the previous script, but there is a possible case in which the starting message about Ginko's Training Academy might not be shown.
In looking for unused Claimed variables I noticed some variables used in WoG scripts which are not in the ERM Help List of the Claimed, so I will be adding them to the updated ERM Help at box.com in a day or two. Merry Christmas! (Hey, I've gotten many presents that didn't impress me much either. Usually clothes. Why do people give me clothes?)
|
| |
|
|
